ASP et SDK

[pepi22]

Bonjour,

J'aimerais savoir comment il est possible de se connecter à une compagnie en utilisant la SDK et ASP. (Un bout de code ou autre référence)

Merci

[Lartis]

Bonjour,

Bien sur!

Il y a même des exemples ASP fournis avec Acomba, dans C:\Fortune\SDK\0C_ACOX.HLP, section Exemples en ASP. La systaxe ressemble beaucoup à celle des exembles VBA.

Code:

<%@ LANGUAGE="VBscript" %>

<%
'***************************************************************
'L'exemple ASP suivant utilise le langage de script VBscript. 
'Il effectue l'ouverture de la société Demo et la connexion de 
'l'usager "Denise" avec son mot de passe.                     
'***************************************************************
%>
<%
'Spécifier où est localisé le SDK.
%>
<%
'Déclaration des interfaces
Dim Acomba
Dim UserIndex

'Déclaration des variables
Dim AcombaPath
Dim CompanyPath
Dim MotDePasse
Dim Error
Dim Exist

'Initialisation de l'interface AcombaX
Set Acomba = Server.CreateObject("AcoX0125.AcombaX")

'Initialisation de l'interface UserKey
Set UserIndex = Server.CreateObject("AcoX0125.UserKey")

'Chemin d'accès de la société à ouvrir
CompanyPath = "C:\F1000.dta\Demo"
'Chemin d'accès des cartes d'enregistrement d'Acomba
AcombaPath  = "C:\Fortune"
'Mot de passe de l'usager
MotDePasse  = "MonMot"

'Vérification de l'existence de la société à ouvrir
Exist = Acomba.CompanyExists(CompanyPath)
If Exist <> 0 Then

'Ouverture de la société Demo
Error = Acomba.OpenCompany(AcombaPath, CompanyPath)
If Error = 0 Then

UserIndex.XBlankKey

'Recherche de l'usager "Denise" pour trouver
'son CardPos

UserIndex.UsNumber = "Denise"
Error = UserIndex.XFindKey(1)

If Error = 0 Then

'Connexion de l'usager "Denise" avec son mot de passe
Error = Acomba.LogCurrentUser(UserIndex.UsCardPos, MotDePasse)
If Error = 0 Then

Response.Write("Connexion de l'usager complétée avec succès.")

Else

Response.Write("Erreur : " & Acomba.GetErrorMessage(Error))

End If

Else

Response.Write("Erreur : " & Acomba.GetErrorMessage(Error))

'Fermeture de la société si l'usager n'est

'pas connecté

Error = Acomba.CloseCompany

If Error <> 0 Then

Response.Write("Erreur : " & Acomba.GetErrorMessage(Error))

End If

End If

Else

Response.Write("Erreur : " & Acomba.GetErrorMessage(Error))

End If

Else
    Response.Write("Dossier de la société invalide.")
End If

'Libération des ressources utilisées par Acomba
Set Acomba = nothing
%>


Vous pouvez aussi utiliser ODBC et ASP sans problèmes.

[pepi22]

Merci beaucoup vous êtes très efficace!

C'est tout ce qu'il me fallait ...

Merci encore.

[bonneaupierrelouis]

Bonjour à tous, je prend une chance même si le message date d'il y a 5 ans.. peut-être aller voir mon nouveau sujet sur le tutoriel fournis par Lartis : https://aideacomba.forum-canada.com/t1670-erreur-asp-sdk-connexion-bd#5327

J’éprouve des difficultés et je me demandais si l'un d'entre-vous pouvait m'aider.

Merci beaucoup !

[Contenu sponsorisé]